next »

[davidp]

So I've been working on this flash game again (learning to code in AS3 again) and now I'm trying to figure out how to change sprite on the fly.

I have sprite (.png) embedded in some class definition (for example player's class), but then i'd like to change that sprite to something else...

Point me in direction? Maybe some code snippet or some good example?

I've been trying to find something usefull around the internets, but normally end up with code blocks larger than my WHOLE game code (and i have background scrolling, some effects, enemies popping up, player movement, etc).

[hatu]

Can you post the whole class here?

Basically it's like this

removeChild(oldSprite);
addChild(newSprite);

[davidp]

player class:

Code:

package  
{
	import flash.display.Bitmap;
	
	[Embed(source='../bin/player.png')]
	
	public class PlayerClass extends Bitmap
	{
		public function PlayerClass() 
		{}
	}
}

[ChevyRay]

Right. Realize that a "Sprite" in the AS3 library represents a graphical object that doubles as a container for more graphical objects. What you've created is a Bitmap, which is a class used for rendering BitmapData objects to the screen.

I suppose you could do something like this:

Code:

package  
{
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	
	public class PlayerClass extends Bitmap
	{
		[Embed(source='../bin/player.png')] private static var ImgPlayer:Class;
		[Embed(source='../bin/player2.png')] private static var ImgPlayer2:Class;
		[Embed(source='../bin/player3.png')] private static var ImgPlayer3:Class;

		private static var playerImage:BitmapData = (new ImgPlayer).bitmapData;
		private static var playerImage2:BitmapData = (new ImgPlayer2).bitmapData;
		private static var playerImage3:BitmapData = (new ImgPlayer3).bitmapData;

		public function PlayerClass() 
		{
			// assign the bitmap image like this
			bitmapData = playerImage;
		}
	}
}

Then you can assign the Bitmap object's bitmapData property to any of those three BitmapData objects on the fly. It's not the most convenient method if you want to display an animated bitmap, but it should work.

Sorry if that code is flawed at all, I was just about to head off to bed.

[davidp]

ook, this looks like it could work tnx, will try it

edit: works like a charm thank a lot chevy!